使用ESP32CAM和VLC播放器DIY监控闭路电视摄像机

基于ESP32-CAM的CCTV摄像机是一个项目，允许您使用ESP32-CAM模块和VLC播放器创建远程监控摄像机。ESP32- cam板是ESP32微控制器和相机模块OV2640的流行组合，适用于捕获图像和流媒体视频。该项目引入了ESP32 CAM模块，这是一个小型但功能强大的相机模块，配备了ESP32微控制器，并利用Wi-Fi功能，使项目具有成本效益和经济实惠。

在这个项目中，我们的CAM模块与Wi-Fi网络无缝集成，将直播视频传输到无线通信中，由连接相同WiFi的设备接收。用户可以通过使用实时监控摄像头馈送的VLC流媒体平台无线观看直播。

在整个项目中，我们将了解设置过程、连接图和演示，以编码ESP32CAM来捕获视频，并展示启动VLC流的步骤。

查看所有以前使用ESP32-CAM创建的监控和流媒体项目：使用Arduino IDE的基于ESP32 CAM的监控机器人

组件的要求

•ESP32凸轮模块

•USB到UART TTL串行转换器/ FTDI模块

•连接电线

•外部5v电源

ESP32凸轮模块

ESP32- cam模块(由AI-Thinker开发)使用ESP32微控制器和OV2640相机传感器，支持Wi-Fi和蓝牙连接，一些关键规格如下：

微控制器：ESP32-D0WDQ6，双核32位，时钟速度高达240 MHz。

摄像头：OV2640, 200万像素分辨率(1600 × 1200像素)。

内存：4mb闪存，大约520-600 KB RAM，外部8MB PSRAM。

支持SD卡读卡器高达4GB。

ESP32-S芯片总共提供32个GPIO引脚;然而，由于其中相当一部分是预留给内部使用的，ESP32-CAM模块只提供10个可用的GPIO引脚。尽管有这种限制，但这些引脚是通用的，可用于接口UART， SPI, I2C， PWM， ADC， DAC和Touch功能，使ESP32-CAM成为各种应用的强大而灵活的平台。

电源引脚包括5v和3.3v。它有一个内置的3.3电压调节器。

FTDI模块

由于ESP32 CAM板没有USB到TTL串行转换器IC。因此唯一的选择是使用FTDI模块使用PC对ESP32板进行编程。下面的图表给你一个关于它的引脚和接口的想法。

一般来说，该模块有6个引脚与微控制器通信。

GND：接地引脚

5V：输出5V版本，输入3.3V版本

TXD：传输数据(从模块输出)

RXD：接收数据(输入到模块)

CTS：清除发送(输入到模块)

DTR：数据终端就绪(从模块输出)

ESP32 CAM和FTDI编程电路图

采用串行通信技术，利用FTDI (USB-to-UART)模块对ESP32 Cam进行编程。FTDI模块作为计算机的USB到ESP-32 CAM的UART接口之间的串行转换器，允许您上传代码并与模块进行交互。

根据连接图，可以将ESP32-CAM与FTDI模块连接，进行编程：

连接FTDI模块的GND和ESP32-CAM的GND。

连接FTDI模块的RX到ESP32-CAM的U0TXD。

将FTDI模块的TX连接到ESP32-CAM的U0RXD。

将FTDI模块上的VCC连接到ESP32-CAM的5V电源引脚上。

重要：将ESP32-CAM的GPIO0到GND排序，使板处于启动模式以进行编程。稍后，必须在程序上传成功后删除排序。

在某些ESP32-CAM板中，您可能会遇到检测器断电错误，这通常是由FTDI (USB转UART)模块供电不足引起的。为了解决这个问题，建议将外部5V电源直接接入ESP32-CAM板。该外部电源将确保ESP32-CAM获得足够的电压，并且可以在不触发断电检测器错误的情况下运行，如下图所示：

ESP32-CAM闭路电视摄像机的Arduino编程代码

我们将使用Arduino IDE对开发板进行编程。该程序为相机模块设置了各种接口引脚，并创建了一个基于网络的流媒体链接，将用于在VLC上进行流媒体。为此，我们需要下载代码草图。你可以在GitHub上找到完整的代码。

下载zip文件中的完整代码，然后解压缩文件夹并解压缩它。打开文件夹后，您将找到一个名为esp32_camera_mjpeg的ino文件，这是我们的代码草图文件。

在Arduino IDE中打开草图文件。由于这是原始代码，因此我们必须根据我们的环境对代码进行一些修改。让我们一起来看看：

在代码的开头，您将找到特定相机模型硬件的定义。默认情况下，将有CAMERA_MODEL_ESP_EYE选择，但我们的模块使用CAMERA_MODEL_AI_THINKER。因此，对前面选择的模型进行注释，并取消对CAMERA_MODEL_AI_THINKER模型的注释。

指定正确的网络凭据，包括SSID和Password，以成功连接到加密的网络。确保您的网络带宽为2.4 GHz，使其与开发板兼容。

OV2640的图像质量和帧大小可以通过下面的代码部分进行调整。

(1600 x 1200)

qvga (320 x 240)

jpeg_quality的取值范围从0到63，数值越小表示图像质量越高。但是，为jpeg_quality设置一个非常低的数字，特别是在更高的分辨率下，可能会导致诸如图像损坏，奇怪的颜色，甚至ESP32-CAM崩溃之类的问题。

为了避免这些问题，在图像质量和内存约束之间找到一个平衡是至关重要的。如果您注意到使用ESP32-CAM拍摄的图像被截成两半，包含奇怪的颜色，或者模块正在经历崩溃，请考虑增加jpeg_quality值以改善图像输出和稳定性。

既然代码已经完成了所有必要的更改，现在是时候继续编译和上传代码了。

在上传代码到ESP32-CAM板之前，请选择正确的板和COM端口。要做到这一点，请遵循以下步骤：

进入Arduino IDE菜单中的“Tools”。

点击“Board”，点击“ESP32 Arduino”，在可选板列表中选择“AI Thinker ESP32- cam”。

注意：如果你在主板中没有找到“ESP32 Arduino”，这意味着主板没有安装在你的IDE中。这是以前的教程，让您深入了解安装ESP32板。

此外，确保FTDI编程器正确连接到模块。此外，请确保GPIO0也接地。GPIO0的接地对于将ESP32-CAM置于编程模式至关重要。

一旦所有这些都完成了，您可以继续编译和上传过程后，选择正确的板和COM端口。

通过Web界面监控直播

上传完成后，将单板从PC上拔下。从ESP32-CAM板上拆除IO0和GND跳线连接，然后将其再次插入PC。打开串口监视器，按下单板上的复位按钮。通过这样做，ESP32-CAM模块将尝试连接到配置的WiFi网络。

串行监视器上将显示MPEG链接。复制链接并在任何浏览器中搜索。你会发现直播开始了。

在VLC上配置直播

现在让我们在VLC媒体应用程序上直播视频。你们中的许多人可能已经在Android或Windows上使用过VLC媒体播放器。我们正在使用这个多功能播放器流媒体，这承诺是一个有趣的，创造性的，和实用的实现。如果你还没有安装播放器，你可以很容易地从Android的Play Store下载，或者使用任何Windows的web浏览器下载。

在您的设备(Android、Windows或任何其他平台)上打开VLC媒体播放器。

在VLC中，进入菜单中的“媒体”，选择“打开网络流”。

在“网络”选项卡中，输入直播视频流的URL。URL应该与显示在串行监视器上或用于web流媒体上的URL相同。

点击“播放”开始直播。

注意：请确保直播流设备连接到与ESP32-CAM板相同的网络。

希望你喜欢和享受这个项目，并从中学到一些有用的东西。

/*

This is a simple MJPEG streaming webserver implemented for AI-Thinker ESP32-CAM and

ESP32-EYE modules.

This is tested to work with VLC and Blynk video widget.

Inspired by and based on this Instructable: $9 RTSP Video Streamer Using the ESP32-CAM Board

(https://www.instructables.com/id/9-RTSP-Video-Streamer-Using-the-ESP32-CAM-Board/)

Board: AI-Thinker ESP32-CAM

*/

#include "src/OV2640.h"

#include

#include

#include

// Select camera model

//#define CAMERA_MODEL_WROVER_KIT

//#define CAMERA_MODEL_ESP_EYE

//#define CAMERA_MODEL_M5STACK_PSRAM

//#define CAMERA_MODEL_M5STACK_WIDE

#define CAMERA_MODEL_AI_THINKER

#include "camera_pins.h"

#define SSID1 "Semicon Media 2.4"

#define PWD1 "cdfiP29to665"

OV2640 cam;

WebServer server(80);

const char HEADER[] = "HTTP/1.1 200 OK\r\n" \

"Access-Control-Allow-Origin: *\r\n" \

"Content-Type: multipart/x-mixed-replace; boundary=123456789000000000000987654321\r\n";

const char BOUNDARY[] = "\r\n--123456789000000000000987654321\r\n";

const char CTNTTYPE[] = "Content-Type: image/jpeg\r\nContent-Length: ";

const int hdrLen = strlen(HEADER);

const int bdrLen = strlen(BOUNDARY);

const int cntLen = strlen(CTNTTYPE);

void handle_jpg_stream(void)

{

char buf[32];

int s;

WiFiClient client = server.client();

client.write(HEADER, hdrLen);

client.write(BOUNDARY, bdrLen);

while (true)

{

if (!client.connected()) break;

cam.run();

s = cam.getSize();

client.write(CTNTTYPE, cntLen);

sprintf( buf, "%d\r\n\r\n", s );

client.write(buf, strlen(buf));

client.write((char *)cam.getfb(), s);

client.write(BOUNDARY, bdrLen);

}

}

const char JHEADER[] = "HTTP/1.1 200 OK\r\n" \

"Content-disposition: inline; filename=capture.jpg\r\n" \

"Content-type: image/jpeg\r\n\r\n";

const int jhdLen = strlen(JHEADER);

void handle_jpg(void)

{

WiFiClient client = server.client();

cam.run();

if (!client.connected()) return;

client.write(JHEADER, jhdLen);

client.write((char *)cam.getfb(), cam.getSize());

}

void handleNotFound()

{

String message = "Server is running!\n\n";

message += "URI: ";

message += server.uri();

message += "\nMethod: ";

message += (server.method() == HTTP_GET) ? "GET" : "POST";

message += "\nArguments: ";

message += server.args();

message += "\n";

server.send(200, "text / plain", message);

}

void setup()

{

Serial.begin(115200);

//while (!Serial); //wait for serial connection.

camera_config_t config;

config.ledc_channel = LEDC_CHANNEL_0;

config.ledc_timer = LEDC_TIMER_0;

config.pin_d0 = Y2_GPIO_NUM;

config.pin_d1 = Y3_GPIO_NUM;

config.pin_d2 = Y4_GPIO_NUM;

config.pin_d3 = Y5_GPIO_NUM;

config.pin_d4 = Y6_GPIO_NUM;

config.pin_d5 = Y7_GPIO_NUM;

config.pin_d6 = Y8_GPIO_NUM;

config.pin_d7 = Y9_GPIO_NUM;

config.pin_xclk = XCLK_GPIO_NUM;

config.pin_pclk = PCLK_GPIO_NUM;

config.pin_vsync = VSYNC_GPIO_NUM;

config.pin_href = HREF_GPIO_NUM;

config.pin_sscb_sda = SIOD_GPIO_NUM;

config.pin_sscb_scl = SIOC_GPIO_NUM;

config.pin_pwdn = PWDN_GPIO_NUM;

config.pin_reset = RESET_GPIO_NUM;

config.xclk_freq_hz = 20000000;

config.pixel_format = PIXFORMAT_JPEG;

// Frame parameters

config.frame_size = FRAMESIZE_UXGA;

//config.frame_size = FRAMESIZE_QVGA;

config.jpeg_quality = 12;

config.fb_count = 2;

#if defined(CAMERA_MODEL_ESP_EYE)

pinMode(13, INPUT_PULLUP);

pinMode(14, INPUT_PULLUP);

#endif

cam.init(config);

IPAddress ip;

WiFi.mode(WIFI_STA);

WiFi.begin(SSID1, PWD1);

while (WiFi.status() != WL_CONNECTED)

{

delay(500);

Serial.print(F("."));

}

ip = WiFi.localIP();

Serial.println(F("WiFi connected"));

Serial.println("");

Serial.println(ip);

Serial.print("Stream Link: http://");

Serial.print(ip);

Serial.println("/mjpeg/1");

server.on("/mjpeg/1", HTTP_GET, handle_jpg_stream);

server.on("/jpg", HTTP_GET, handle_jpg);

server.onNotFound(handleNotFound);

server.begin();

}

void loop()

{

server.handleClient();

}

本文编译自iotdesignpro